{-# LANGUAGE DeriveGeneric, FlexibleInstances #-}

{- | Main types for debug-me
 -
 - Note that changing types in ways that change the JSON serialization
 - changes debug-me's wire format.
 -}

module Types (
	module Types,
	Val(..)
) where

import Val
import Memory
import Json

-- | Things that the developer sees.
data Seen = Seen
	{ seenData :: Val
	}
	deriving (Show, Generic)

instance DataSize Seen where
	dataSize = dataSize . seenData

-- | Things that the developer enters.
data Entered = Entered
	{ enteredData :: Val
	, echoData :: Val
	-- ^ Data that is expected to be Seen, but has not been received
	-- at the time this was entered.
	}
	deriving (Show, Generic)

instance DataSize Entered where
	dataSize e = dataSize (enteredData e) + dataSize (echoData e)

-- | High level protocol.
data Proto a
	= Proto a
	-- ^ either Entered or Seen
	| Rejected (Activity Entered)
	-- ^ sent by user to indicate when an Entered value was rejected.
	deriving (Show, Generic)

instance DataSize a => DataSize (Proto a) where
	dataSize (Proto a) = dataSize a
	dataSize (Rejected a) = dataSize a

-- | A Proto activity (either Entered or Seen) with a pointer
-- to the Activity before this one.
--
-- The Signature is over both the data in the activity, and its pointer.
data Activity a = Activity
	{ activity :: Proto a
	, prevActivity :: (Maybe Hash)
	, signature :: Signature
	}
	deriving (Show, Generic)

instance DataSize a => DataSize (Activity a) where
	dataSize a = dataSize (activity a) 
		+ maybe 0 dataSize (prevActivity a) 
		+ dataSize (signature a)

data Hash = Hash
	{ hashMethod :: HashMethod
	, hashValue :: Val
	}
	deriving (Show, Generic, Eq)

instance DataSize Hash where
	dataSize (Hash { hashMethod = SHA256 }) = 64
	dataSize (Hash { hashMethod = SHA3 }) = 56

-- | We use SHA256. (SHA3 is included to future proof, and because it
-- improves the generated JSON.)
data HashMethod = SHA256 | SHA3
	deriving (Show, Generic, Eq)

data Signature 
	= Ed25519 Val
	| Unsigned
	-- ^ Not used, but included to future-proof the JSON format.
	deriving (Show, Generic)

instance DataSize Signature where
	dataSize (Ed25519 _) = 64
	dataSize Unsigned = 0

instance ToJSON Seen
instance FromJSON Seen
instance ToJSON Entered
instance FromJSON Entered
instance ToJSON (Activity Seen)
instance FromJSON (Activity Seen)
instance ToJSON (Activity Entered)
instance FromJSON (Activity Entered)
instance ToJSON Hash
instance FromJSON Hash
instance ToJSON HashMethod
instance FromJSON HashMethod

instance ToJSON (Proto Seen) where
	toJSON = genericToJSON sumOptions
	toEncoding = genericToEncoding sumOptions
instance FromJSON (Proto Seen) where
	parseJSON = genericParseJSON sumOptions

instance ToJSON (Proto Entered) where
	toJSON = genericToJSON sumOptions
	toEncoding = genericToEncoding sumOptions
instance FromJSON (Proto Entered) where
	parseJSON = genericParseJSON sumOptions

instance ToJSON Signature where
	toJSON = genericToJSON sumOptions
	toEncoding = genericToEncoding sumOptions
instance FromJSON Signature where
	parseJSON = genericParseJSON sumOptions