path: root/Types.hs

{-# LANGUAGE DeriveGeneric, FlexibleInstances, FlexibleContexts #-}

{- | Main types for debug-me
 -
 - Note that changing types in ways that change the Binary serialization
 - changes debug-me's wire format. Changing types in ways that change the
 - aeson serialization changes debug-me's log format.
 -}

module Types (
	module Types,
	Val(..)
) where

import Val
import Memory
import Serialization

import Data.Time.Clock.POSIX

-- | Things that the developer sees.
data Seen = Seen
	{ seenData :: Val
	}
	deriving (Show, Generic)

instance DataSize Seen where
	dataSize = dataSize . seenData

-- | Things that the developer enters.
data Entered = Entered
	{ enteredData :: Val
	, echoData :: Val
	-- ^ Data that is expected to be Seen, but has not been received
	-- at the time this was entered.
	}
	deriving (Show, Generic)

instance DataSize Entered where
	dataSize e = dataSize (enteredData e) + dataSize (echoData e)

-- | A message in the protocol.
data Message a
	= ActivityMessage (Activity a)
	| ControlMessage Control
	deriving (Show, Generic)

instance DataSize a => DataSize (Message a) where
	dataSize (ActivityMessage a) = dataSize a
	dataSize (ControlMessage c) = dataSize c

-- | An activity (either Entered or Seen) with a pointer
-- to a previous Activity, and the amount of time elapsed since the
-- previous Activity.
--
-- The Signature is over both the data in the activity, and its pointer.
--
-- Note that the Signature is included in the Hash of an Activity,
-- which is why it's part of the Activity.
data Activity a = Activity
	{ activity :: a
	, prevActivity :: Maybe Hash
	, elapsedTime :: Maybe ElapsedTime
	, activitySignature :: Signature
	}
	deriving (Show, Generic)

instance DataSize a => DataSize (Activity a) where
	dataSize a = dataSize (activity a) 
		+ maybe 0 dataSize (prevActivity a)
		+ maybe 0 dataSize (elapsedTime a)
		+ dataSize (activitySignature a)

-- | A control message, which can be sent asynchronously.
data Control = Control
	{ control :: ControlAction
	, controlSignature :: Signature
	}
	deriving (Show, Generic)

instance DataSize Control where
	dataSize c = dataSize (control c)
		+ dataSize (controlSignature c)

data ControlAction
	= Rejected (Activity Entered)
	-- ^ sent by user to indicate when an Entered value was rejected.
	| SessionKey (PerhapsSigned PublicKey)
	-- ^ sent by user at start, and later by developer,
	-- to indicate their session key
	| SessionKeyAccepted PublicKey
	-- ^ sent by the user to in response to SessionKey
	| SessionKeyRejected PublicKey
	-- ^ sent by the user to in response to SessionKey
	deriving (Show, Generic)

instance DataSize ControlAction where
	dataSize (Rejected a) = dataSize a
	dataSize (SessionKey k) = dataSize k
	dataSize (SessionKeyAccepted k) = dataSize k
	dataSize (SessionKeyRejected k) = dataSize k

data Hash = Hash
	{ hashMethod :: HashMethod
	, hashValue :: Val
	}
	deriving (Show, Generic, Eq)

instance DataSize Hash where
	dataSize (Hash { hashMethod = SHA256 }) = 64
	dataSize (Hash { hashMethod = SHA3 }) = 56

-- | We use SHA256. (SHA3 is included to future proof, and because it
-- improves the generated JSON.)
data HashMethod = SHA256 | SHA3
	deriving (Show, Generic, Eq)

data Signature 
	= Ed25519Signature Val
	| OtherSignature Val
	-- ^ Not used, but included to future-proof the JSON format.
	deriving (Show, Generic)

instance DataSize Signature where
	dataSize (Ed25519Signature v) = dataSize v
	dataSize (OtherSignature v) = dataSize v

-- | A public key used for a debug-me session.
data PublicKey = PublicKey Val
	deriving (Show, Generic, Eq)

instance DataSize PublicKey where
	-- ed25519 public keys are 32 bytes
	dataSize (PublicKey _) = 32

-- | A value that may be gpg signed.
data PerhapsSigned a
	= GpgSigned a GpgSig
	| UnSigned a
	deriving (Show, Generic, Eq)

instance DataSize a => DataSize (PerhapsSigned a) where
	dataSize (GpgSigned a sig) = dataSize a + dataSize sig
	dataSize (UnSigned a) = dataSize a

-- | A signature made with a gpg key.
newtype GpgSig = GpgSig Val
	deriving (Show, Generic, Eq)

instance DataSize GpgSig where
	dataSize (GpgSig s) = dataSize s

-- | Elapsed time in seconds.
newtype ElapsedTime = ElapsedTime Double
	deriving (Show, Generic, Eq)

mkElapsedTime :: POSIXTime -> POSIXTime -> ElapsedTime
mkElapsedTime start end = ElapsedTime $ fromRational $ toRational (end - start)

instance DataSize ElapsedTime where
	dataSize _ = 16 -- 128 bit Double

data LogMessage
	= User (Message Seen)
	| Developer (Message Entered)
	deriving (Show, Generic)

instance Binary ElapsedTime
instance ToJSON ElapsedTime
instance FromJSON ElapsedTime

instance DataSize LogMessage where
	dataSize (User a) = dataSize a
	dataSize (Developer a) = dataSize a

instance Binary LogMessage
instance ToJSON LogMessage where
	toJSON = genericToJSON sumOptions
	toEncoding = genericToEncoding sumOptions
instance FromJSON LogMessage where
	parseJSON = genericParseJSON sumOptions

instance Binary Seen
instance ToJSON Seen
instance FromJSON Seen
instance Binary Entered
instance ToJSON Entered
instance FromJSON Entered
instance Binary (Activity Seen)
instance ToJSON (Activity Seen)
instance FromJSON (Activity Seen)
instance Binary (Activity Entered)
instance ToJSON (Activity Entered)
instance FromJSON (Activity Entered)
instance Binary Control
instance ToJSON Control
instance FromJSON Control
instance Binary Hash
instance ToJSON Hash
instance FromJSON Hash
instance Binary HashMethod
instance ToJSON HashMethod
instance FromJSON HashMethod
instance Binary PublicKey
instance ToJSON PublicKey
instance FromJSON PublicKey
instance Binary GpgSig
instance ToJSON GpgSig
instance FromJSON GpgSig

instance Binary (Message Seen)
instance ToJSON (Message Seen) where
	toJSON = genericToJSON sumOptions
	toEncoding = genericToEncoding sumOptions
instance FromJSON (Message Seen) where
	parseJSON = genericParseJSON sumOptions

instance Binary (Message Entered)
instance ToJSON (Message Entered) where
	toJSON = genericToJSON sumOptions
	toEncoding = genericToEncoding sumOptions
instance FromJSON (Message Entered) where
	parseJSON = genericParseJSON sumOptions

instance Binary Signature
instance ToJSON Signature where
	toJSON = genericToJSON sumOptions
	toEncoding = genericToEncoding sumOptions
instance FromJSON Signature where
	parseJSON = genericParseJSON sumOptions

instance Binary ControlAction
instance ToJSON ControlAction where
	toJSON = genericToJSON sumOptions
	toEncoding = genericToEncoding sumOptions
instance FromJSON ControlAction where
	parseJSON = genericParseJSON sumOptions

instance Binary (PerhapsSigned PublicKey)
instance ToJSON (PerhapsSigned PublicKey) where
	toJSON = genericToJSON sumOptions
	toEncoding = genericToEncoding sumOptions
instance FromJSON (PerhapsSigned PublicKey) where
	parseJSON = genericParseJSON sumOptions