blob: fa5948e00a540ce5de0ff3a410d635309764af06 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
|
;;; Consfigurator -- Lisp declarative configuration management system
;;; Copyright (C) 2021 Sean Whitton <spwhitton@spwhitton.name>
;;; This file is free software; you can redistribute it and/or modify
;;; it under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3, or (at your option)
;;; any later version.
;;; This file is distributed in the hope that it will be useful,
;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;; You should have received a copy of the GNU General Public License
;;; along with this program. If not, see <http://www.gnu.org/licenses/>.
(in-package :consfigurator.property.apt)
(named-readtables:in-readtable :interpol-syntax)
;;;; Static definitions
(defmacro with-maybe-update (form)
`(handler-case ,form
(run-failed ()
(apt-get :princ "update")
,form)))
(define-constant +sections+ '("main" "contrib" "non-free") :test #'equal)
;;;; Properties
(defprop installed :posix (&rest packages)
"Ensure all of the apt packages PACKAGES are installed."
(:desc #?"apt installed @{packages}")
(:hostattrs
(declare (ignore packages))
(os:required 'os:debianlike))
(:check
(all-installed-p packages))
(:apply
(with-maybe-update (apt-get :princ "-y" "install" packages))))
(defprop removed :posix (&rest packages)
"Ensure all of the apt packages PACKAGES are removed."
(:desc #?"apt removed @{packages}")
(:hostattrs
(declare (ignore packages))
(os:required 'os:debianlike))
(:check
(none-installed-p packages))
(:apply
(apt-get :princ "-y" "remove" packages)))
(defproplist service-installed-running :posix (package)
"Where PACKAGE installs a service named PACKAGE, ensure it is installed and
running.
E.g. (APT:SERVICE-INSTALLED-RUNNING \"apache2\")."
(:desc #?"${package} installed and running")
(installed package)
(service:running package))
(defprop mirror :posix (uri)
(:desc #?"${uri} apt mirror selected")
(:hostattrs
(pushnew-hostattrs :apt.mirror uri)))
(defproplist uses-parent-mirror :posix ()
(:desc #?"Uses parent's apt mirror")
(mirror (get-parent-hostattrs-car :apt.mirror)))
(defprop proxy :posix (uri)
(:desc #?"${uri} apt proxy selected")
(:hostattrs
(pushnew-hostattrs :apt.proxy uri))
(:apply
(file:has-content "/etc/apt/apt.conf.d/20proxy"
(format nil "Acquire::HTTP::Proxy \"~A\";~%" uri))))
(defproplist uses-parent-proxy :posix ()
(:desc #?"Uses parent's apt proxy")
(proxy (get-parent-hostattrs-car :apt.proxy)))
(defproplist uses-local-cacher :posix ()
(:desc "apt uses local apt cacher")
(service-installed-running "apt-cacher-ng")
(proxy "http://localhost:3142"))
(defun get-mirrors ()
(or (get-hostattrs :apt.mirror) (call-with-os #'get-default-mirrors)))
(defmethod get-default-mirrors ((os os:debian))
'("http://deb.debian.org/debian"))
(defprop standard-sources.list :posix ()
(:desc "Standard sources.list")
(:apply
(file:has-content "/etc/apt/sources.list"
(call-with-os #'standard-sources-for))))
(defmethod standard-sources-for ((os os:debian))
(let* ((suite (os:debian-suite os))
(archive (mapcar (lambda (m) (list* m suite +sections+))
(get-mirrors)))
(security-suite (if (memstring= suite '("stretch" "jessie" "buster"))
#?"${suite}/updates"
#?"${suite}-security"))
(security (and (not (subtypep (type-of os) 'os:debian-unstable))
(list
(list* "http://security.debian.org/debian-security"
security-suite +sections+)))))
(mapcan (lambda (l) (list #?"deb @{l}" #?"deb-src @{l}"))
(nconc archive security))))
;;;; Reports on installation status
(defun apt-cache-policy (packages)
(runlines :env '(:LANG "C") "apt-cache" "policy" packages))
(define-constant apt-cache-policy-installed #?/^\s+Installed:\s+(?!\(none\))/
:test #'string=)
(defun all-installed-p (packages)
(loop with n = 0
for line in (apt-cache-policy packages)
when (re:scan apt-cache-policy-installed line)
do (incf n)
finally (return (= n (length packages)))))
(defun none-installed-p (packages)
(loop for line in (apt-cache-policy packages)
never (re:scan apt-cache-policy-installed line)))
;;;; Utilities
(defun apt-get (&rest args)
(apply #'run
:env '(:DEBIAN_FRONTEND "noninteractive"
:APT_LISTCHANGES_FRONTEND "none")
"apt-get" args))
|
